Selasa, 26 April 2011

Aplikasi Waktu Beranimasi

Pada kali ini saya akan membuat sebuah aplikasi waktu (Jam dan Tanggal) dimana saat form tampil (load) dan keluar (unload) bisa beranimasi. Mari kita langsung saja ke TKP.

Buatlah Projek Baru (New project, standar exe)
Pada form tambahkan control/object sbb:
1. 2 buah label dengan nama masing-masing lblWaktu dan lblTanggal. Lalu hapus properti caption-nya (kosongkan).
2. CommandButton dengan nama 'cmdFormat' , Caption = "12"
3. Tambahkan sebuah timer pada form.

Aturlah ukuran dan tampilannya sesuai selera, serta tambahkan label judul atau yang lainnya.
Setelah selesai, copas code dibawah ini dan letakkan pada halaman kode (untuk menampilkan halaman kode, klik 2 kali pada form).
Option Explicit

'Dibuat oleh Yosa Cahya
'Email: yosa.cahya@gmail.com
'Blog : tutorialvb6.blogspot.com
Dim wkt As String, Tanggal As Variant
Dim TimeFormat As Byte
Dim hijri As Boolean
Const AW_CENTER = &H10
Const AW_HIDE = &H10000
Const AW_BLEND = &H80000
Private Declare Function AnimateWindow Lib "user32" _
    (ByVal hwnd As Long, _
    ByVal dwTime As Long, _
    ByVal dwFlags As Long) As Boolean


Private Sub Form_Load()
 Me.AutoRedraw = True
 Animasikan Me.hwnd, 1000, AW_CENTER
 Me.Show
 Me.Refresh
 TimeFormat = 1
 Timer1.Interval = 1000
 lblWaktu.Caption = Format(Time, "h:mm:ss")
 lblWaktu.Refresh
 lblTanggal.Caption = Hari(Date) & ", " & Format(Date, "dd mmmm yyyy")
 lblTanggal.Refresh
End Sub

Private Sub Form_Unload(Cancel As Integer)
 Animasikan Me.hwnd, 1000, AW_BLEND Or AW_HIDE
End Sub

Private Sub cmdFormat_Click()
If cmdFormat.Caption = "12" Then
  cmdFormat.Caption = "24"
  TimeFormat = 0
   Else
  cmdFormat.Caption = "12"
  TimeFormat = 1
End If
End Sub

Private Sub lblTanggal_Click()
If hijri = False Then
 Calendar = vbCalHijri
 hijri = True
 Else
 Calendar = vbCalGreg
 hijri = False
 End If
End Sub

Private Sub lblTanggal_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
 lblTanggal.ToolTipText = "Klik pada tanggal ini untuk merubah Kalender"
End Sub


Private Sub lblWaktu_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
 lblWaktu.ToolTipText = "Klik tombol disamping kanan untuk merubah format jam"
End Sub

Private Sub Timer1_Timer()
 wkt = Time
 Tanggal = Date
 If TimeFormat = 0 Then
    wkt = Format(Time, "HH:mm:ss AMPM")
    wkt = Replace(wkt, "AM", "am")
    wkt = Replace(wkt, "PM", "pm")
 Else
    wkt = Format(Time, "h:mm:ss")
 End If
 lblWaktu.Caption = wkt
 lblWaktu.Refresh
 If hijri = False Then
 lblTanggal.Caption = Hari(Tanggal) & ", " & Format(Tanggal, "dd mmmm yyyy")
 Else
 lblTanggal.Caption = Hari(Tanggal) & ", " & FormatDateTime(Tanggal, vbShortDate) & " Hij"
End If
End Sub

Function Hari(ByVal tgl As Variant) As String
Dim poe As Byte
 poe = Weekday(tgl, vbSunday)
 Select Case poe
  Case 1: Hari = "Minggu"
  Case 2: Hari = "Senin"
  Case 3: Hari = "Selasa"
  Case 4: Hari = "Rabu"
  Case 5: Hari = "Kamis"
  Case 6: Hari = "Jum'at"
  Case 7: Hari = "Sabtu"
 End Select
End Function

Function Animasikan(Win_hWnd As Long, AnimationTime As Long, flag As Long)
  AnimateWindow Win_hWnd, AnimationTime, flag
End Function

Jalankan program dengan menekan F5 dan lihat hasilnya.
Bagi anda yang ingin melihat contoh aplikasi yang sudah jadi dari artikel ini, silahkan download disini, dijamin direct link alias tanpa iklan.

Selamat mencoba, Semoga bermanfa'at.
Baca Selengkapnya...

Minggu, 10 April 2011

Membuat aplikasi penjumlahan Lanjutan

Latihan ini adalah kelanjutan dari latihan sebelumnya yaitu  'ProjectJumlah'.
Tambahkan sebuah form pada ProjectJumlah, caranya, pada menu klik Project > add Form. Akan tampil jendela AddForm, dan pilihan pertama (default)nya adalah New > Form. Maka tinggal klik open. Beri nama 'frmJumlah2'.


Selanjutnya Copy semua control pada frmJumlah dan paste pada frmJumlah2. Aturlah ukuran form sesuai kebutuhan agar semua objek control terlihat. Rubah nama 'cmdKeluar' menjadi 'cmdKembali' dan ganti caption-nya dengan "Kembali".


Buka lagi frmJumlah dan tambahkan sebuah CommandButton, berilah nama 'cmdLanjutan'. Ini digunakan untuk memanggil frmJumlah2 yang sedang kita buat sekarang ini. Dobel klik pada 'cmdLanjutan' isikan code berikut:

 Load frmJumlah2
 frmJumlah2.Show
 Me.Hide

 jadi lengkapnya menjadi sbb:

Private Sub cmdLanjutan_Click()
 Load frmJumlah2
 frmJumlah2.Show
 Me.Hide
End Sub

Selanjutnya buka frmJumlah2, copy code dibawah ini, paste pada halaman code frmJumlah2.

Option Explicit
Dim input1 As Long
Dim input2 As Long
Dim hasil As Long

Private Sub cmdJumlah_Click()
'cek jika user telah mengisi input
If Text1.Text = "" Or Text2.Text = "" Then
 MsgBox "Ma'af, Isi dulu angkanya!"
 Text1.SetFocus
 Exit Sub
End If
'mengambil data dari user
'pada code dibawah ini digunakan fungsi "replace" karena
'teks pada text1 dan text2 menggunakan Format "###,##0"
'ingat, koma pada vb dibaca titik pada format angka indonesia
 input1 = Val(Replace(Text1.Text, ".", ""))
 input2 = Val(Replace(Text2.Text, ".", ""))
 'menghitung hasil
 hasil = input1 + input2
 'menampilkan hasil pada text3
 Text3.Text = hasil
 Text3.Refresh  'untuk memastikan tampilan
End Sub

Private Sub cmdHapus_Click()
 Text1.Text = ""
 Text2.Text = ""
 Text3.Text = ""
 'tempatakan kursor pada text1
 Text1.SetFocus
End Sub

Private Sub cmdKembali_Click()
 Load frmJumlah
 frmJumlah.Show
 Unload Me
End Sub

Private Sub text1_KeyPress(KeyAscii As Integer)
'agar hanya angka yang boleh diketikkan
If Not ((KeyAscii > 47 And KeyAscii < 58) Or KeyAscii = vbKeyBack Or KeyAscii = vbKeyReturn) Then
   KeyAscii = 0
   Text1.Text = ""
   Beep
    Else
    'agar jika di tekan enter, kursor berpindah ke text2
    If KeyAscii = vbKeyReturn Then Text2.SetFocus
  End If
End Sub

Private Sub text2_KeyPress(KeyAscii As Integer)
'agar hanya angka yang boleh diketikkan
If Not ((KeyAscii > 47 And KeyAscii < 58) Or KeyAscii = vbKeyBack Or KeyAscii = vbKeyReturn) Then
   KeyAscii = 0
   Text2.Text = ""
   Beep
    Else
    'agar jika di tekan enter, cmdJumlah dieksekusi
    If KeyAscii = vbKeyReturn Then cmdJumlah_Click
  End If
End Sub

Private Sub text1_KeyUp(KeyCode As Integer, Shift As Integer)
   Text1.Text = Format(Text1.Text, "###,##0")
   Text1.SelStart = Len(Text1.Text)
End Sub

Private Sub text2_KeyUp(KeyCode As Integer, Shift As Integer)
   Text2.Text = Format(Text2.Text, "###,##0")
   Text2.SelStart = Len(Text2.Text)
End Sub

Private Sub Text3_Change()
 Text3.Text = Format(Text3.Text, "###,##0")
End Sub

Cobalah test dengan mengklik menu Run > Start atau icon Start, atau bisa juga menekan F5 pada keyboard. Bandingkan hasilnya dengan frmJumlah pada latihan sebelumnya.
Selamat mencoba.
Baca Selengkapnya...

Sabtu, 09 April 2011

Membuat aplikasi penjumlahan sederhana

Buatlah Projek Baru (New project, standar exe) dan beri nama 'ProjectJumlah'
Rubah nama pada "form1" menjadi "frmJumlah".
Pada frmJumlah tambahkan control/object sbb:
  1. 3 buah textBox dengan nama masing-masing Text1, text2, dan text3. Lalu hapus properti text-nya(kosongkan)
  2. CommandButton dengan nama 'cmdJumlah' , Caption  "="
  3. CommandButton dengan nama 'cmdHapus' , Caption  "Hapus"
  4. CommandButton dengan nama 'cmdKeluar' , Caption  "Keluar"
  5. Buatlah label dengan caption "+"

Aturlah ukuran dan tampilannya sesuai selera, serta tambahkan label judul atau yang lainnya.
Lalu urutkan secara horisontal Text1 -- label "+" -- Text2 -- cmdJumlah -- Text3   pada baris pertama.
Kemudian dibawahnya urutkan   cmdHapus -- cmdKeluar


Setelah selesai, copy code dibawah ini dan letakkan pada halaman kode (untuk menampilkan halaman kode, klik 2 kali pada form).

Option Explicit

Dim input1 As Long
Dim input2 As Long
Dim hasil As Long

Private Sub cmdJumlah_Click()
'mengambil data dari user
 input1 = Val(Text1.Text)
 input2 = Val(Text2.Text)
 'menghitung hasil
 hasil = input1 + input2
 'menampilkan hasil pada text3
 Text3.Text = hasil
End Sub

Private Sub cmdHapus_Click()
 Text1.Text = ""
 Text2.Text = ""
 Text3.Text = ""
 'tempatakan kursor pada text1
 Text1.SetFocus
End Sub

Private Sub cmdKeluar_Click()
 End
End Sub

Cobalah test dengan mengklik menu Run > Start atau icon Start, atau bisa juga menekan F5 pada keyboard. Lihatlah hasilnya.
Baca Selengkapnya...